透過資料庫上傳下載檔案

在ASP時候，寫個上傳檔案都很麻煩，因為ASP本身沒有支援上傳的物件，必須使用第三方物件來進行上傳功能的實作，到了ASP.NET上傳實在很簡單，拉個FileUpload物件，寫簡單的幾行程式，馬上可以有上傳功能。

有了上傳，那下載呢？

下載就很笨，通常是網頁帶「Link」的方式，例如：「http://localhost/files/KKBruce.zip」這樣的方式來讓人下載。好一點的架個FTP，但還是寫個管理Link資料庫及程式，例如：「http://localhost/files/download.asp?id=1」取出「ftp://localhost/files/bruce/blog.zip」來讓使用者下載。久而久之，檔案一多還是不好管理，又要管檔案，又要管理Link！

所以想就使用「資料庫」來管理，這裡指的資料庫不是那種管理「路徑」的Table，而且將檔案整個存到Table裡，需要時再取出來使用，以下我們就來實作上傳檔案至資料庫，由資料庫取出檔案下載兩部份。

****** Object:  Table [dbo].[Files]    Script Date: 08/26/2010 17:12:17 ******/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

SET ANSI_PADDING ON
GO

CREATE TABLE [dbo].[Files](
 [uid] [int] IDENTITY(1,1) NOT NULL,
 [Name] [nvarchar](50) NOT NULL,
 [Body] [varbinary](max) NOT NULL,
 [Size] [decimal](18, 0) NOT NULL,
 [SaveDateTime] [datetime] NOT NULL,
 [LastUseDateTime] [datetime] NULL
) ON [PRIMARY]

GO

SET ANSI_PADDING OFF
GO

我們先建一個資料表，裡面最重要的是「Body」，Body就是要儲存檔案的地方，而一般網路資料或書籍資料都是使用「Image資料類型」，但查看MSDN後發現，如果你是使用SQL Server 2005以後的版本，請改使用請改用 nvarchar(max)、varchar(max) 和 varbinary(max)。

在未來的 Microsoft SQL Server 版本中，將移除 ntext、text 和 image 等資料類型。請避免在新的開發工作中使用這些資料類型，並規劃修改目前在使用這些資料類型的應用程式。請改用 nvarchar(max)、varchar(max) 和 varbinary(max)。

以上是要注意的地方。

接下來我們來實作上傳檔案到資料庫，然後再從資料庫下載檔案。

新增Default.aspx在UI部份：

<div>
        <asp:FileUpload ID="FU" runat="server" />
     
        <asp:Button ID="SaveFile" runat="server" Text="上傳" />
        <br />
        <br />
        編號：<asp:TextBox ID="TextBox1" runat="server"></asp:TextBox>
 <asp:Button ID="DownFile" runat="server" Text="下載" />
    </div>

我們針對SaveFile及DownFile來撰寫程式碼：

SaveFile事件：

Protected Sub SaveFile_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles SaveFile.Click
        ' 先確認有選擇檔案
        If Not FU.HasFile Then
            Response.Write("沒有上傳的檔案！")
            Response.End()
        End If

        ' 檔案存進資料庫都是「二進位」，所以使用Byte
        ' buf陣列依檔案大小來建立
        ' 陣列由0開始，所以減1
        Dim buf(Me.FU.PostedFile.ContentLength - 1) As Byte
        Me.FU.PostedFile.InputStream.Read(buf, 0, Me.FU.PostedFile.ContentLength)

        Dim conn As New SqlConnection(WebConfigurationManager.ConnectionStrings("SCS").ConnectionString)

        ' 將參考及欄位對應起來
        Dim cmd As New SqlCommand("INSERT INTO Files(Name,Body,Size,SaveDateTime) VALUES (@filename,@body,@size, @sdt);", conn)
        cmd.Parameters.AddWithValue("@filename", FU.PostedFile.FileName)
        ' 將二進位檔放入資料庫中
        cmd.Parameters.AddWithValue("@body", buf)
        cmd.Parameters.AddWithValue("@size", FU.PostedFile.ContentLength.ToString)
        cmd.Parameters.AddWithValue("@sdt", Now)

        Try
            Dim rs As Integer
            conn.Open()
            rs = cmd.ExecuteNonQuery
            Response.Write("新增成功")
        Catch ex As Exception
            Response.Write(ex)
        Finally
            cmd.Cancel()
            cmd.Dispose()
            conn.Close()
        End Try
    End Sub

DownFile事件：

Protected Sub DownFile_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles DownFile.Click
        ' 由輸入
        Dim id As Integer

        If String.IsNullOrEmpty(Me.TextBox1.Text) Then
            Response.Write("請輸入下載ID編號")
            Response.End()
        Else
            id = Me.TextBox1.Text
        End If

        Dim conn As New SqlConnection(WebConfigurationManager.ConnectionStrings("SCS").ConnectionString)
        Dim cmd As New SqlCommand("Select * from Files Where uid = @id", conn)
        cmd.Parameters.AddWithValue("@id", id)

        Dim dr As SqlDataReader

        Try
            conn.Open()
            dr = cmd.ExecuteReader
            ' 將資料取出，輸出
            If dr.Read Then
                Response.ClearHeaders()
                Response.Clear()
                Response.Expires = 0
                Response.Buffer = True

                ' Getxxx效能較佳
                Dim Name As String = dr.GetString(1)
                ' 進行AddHeader設定
                Response.AddHeader("Accept-Language", "zh-tw")
                ' 設定輸出檔案及類型
                Response.AddHeader("content-disposition", "attachment; filename=" & Chr(34) & Name & Chr(34))
                Response.ContentType = "Application/octet-stream"
                ' 進行「二進位」輸出，使用BinaryWrite方法
                Response.BinaryWrite(dr("Body"))
                ' 將緩衝輸出
                Response.Flush()
                Response.Close()
                ' 請參考討論，不要使用Response.End()
                ' http://www.blueshop.com.tw/board/FUM20041006161839LRJ/BRD20100824142739D3F.html
                'Response.End()
            End If
            Response.End()
        Catch ex As Exception
            Response.Write(ex)
        Finally
            cmd.Cancel()
            cmd.Dispose()
            conn.Close()
        End Try
    End Sub

其實不難：

1. 將檔案轉為Byte，然後存進資料庫的二進位欄位；
2. 取出資料，進行二進位輸出。

不管是Excel、Word、MP3、Text、ZIP…反正只要是檔案都可以上傳及下載。以上還有很多可以改進的地方，例如統計的部份，或使用其他方式(Session…)來取得下載檔案。

參考：

• 資料類型
• ntext、text 和 image
• binary 和 varbinary